仕掛けシグナル、手仕舞いシグナルともに2本の移動平均線の交差を利用します。

仕掛けシグナルの長期移動平均線より短い期間の移動平均線を使うことで、次の仕掛けシグナルより早く手仕舞いシグナルが出ることになります。

手仕舞いシグナル

<aside> 💡 売りポジションの手仕舞い（買いシグナル）：２本前から１本前にかけて短期移動平均線が手仕舞い用移動平均線を下から上に交差したとき 買いポジションの手仕舞い（売りシグナル）：２本前から１本前にかけて短期移動平均線が手仕舞い用長期移動平均線を上から下に交差したとき

</aside>

コード

//共通ライブラリ
#include "LibEA.mqh"

sinput double Lots = 0.1; //売買ロット数

//ティック時実行関数
void Tick()
{
   int sig_entry = EntrySignal(); //仕掛けシグナル
   int sig_exit = ExitSignal(); //手仕舞いシグナル
   //成行売買
   MyOrderSendMarket(sig_entry, sig_exit, Lots);
}

input int FastMAPeriod = 20; //短期移動平均の期間
input int SlowMAPeriod = 50; //長期移動平均の期間

//仕掛けシグナル関数
int EntrySignal()
{
   //１本前と２本前の移動平均
   double FastMA1 = iMA(_Symbol, 0, FastMAPeriod, 0, MODE_SMA, PRICE_CLOSE, 1);
   double FastMA2 = iMA(_Symbol, 0, FastMAPeriod, 0, MODE_SMA, PRICE_CLOSE, 2);
   double SlowMA1 = iMA(_Symbol, 0, SlowMAPeriod, 0, MODE_SMA, PRICE_CLOSE, 1);
   double SlowMA2 = iMA(_Symbol, 0, SlowMAPeriod, 0, MODE_SMA, PRICE_CLOSE, 2);

   int ret = 0; //シグナルの初期化

   //買いシグナル
   if(FastMA2 <= SlowMA2 && FastMA1 > SlowMA1) ret = 1;
   //売りシグナル
   if(FastMA2 >= SlowMA2 && FastMA1 < SlowMA1) ret = -1;

   return ret; //シグナルの出力
}

input int ExitMAPeriod = 30; //手仕舞い用移動平均の期間

//手仕舞いシグナル関数
int ExitSignal()
{
   //１本前と２本前の移動平均
   double FastMA1 = iMA(_Symbol, 0, FastMAPeriod, 0, MODE_SMA, PRICE_CLOSE, 1);
   double FastMA2 = iMA(_Symbol, 0, FastMAPeriod, 0, MODE_SMA, PRICE_CLOSE, 2);
   double SlowMA1 = iMA(_Symbol, 0, ExitMAPeriod, 0, MODE_SMA, PRICE_CLOSE, 1);
   double SlowMA2 = iMA(_Symbol, 0, ExitMAPeriod, 0, MODE_SMA, PRICE_CLOSE, 2);

   int ret = 0; //シグナルの初期化

   //買いシグナル
   if(FastMA2 <= SlowMA2 && FastMA1 > SlowMA1) ret = 1;
   //売りシグナル
   if(FastMA2 >= SlowMA2 && FastMA1 < SlowMA1) ret = -1;

   return ret; //シグナルの出力
}

説明

仕掛けシグナルでは、短期移動平均の期間を20、長期移動平均の期間を50としたのに対し、手仕舞いシグナルでは、短期移動平均の期間を20、長期移動平均の期間を30としています。

この場合、手仕舞いシグナルの方が仕掛けシグナルより先に出ることになるので、MyOrderSendMarket() の第2引数には、sig_exitのみを代入しています。